Google Play

매매일지 엑셀 양식 만들기 — 열 구성과 승률·MDD 수식

엑셀 매매일지는 한 행에 거래 하나를 두고 ‘날짜·통화쌍·방향·랏·진입가·손절가·청산가·pip·손익·진입 이유·원칙 준수·감정’을 옆으로 늘어놓은 뒤, 다른 칸에 COUNTIF와 AVERAGEIF로 승률과 평균 손익을 내면 기본 양식이 완성됩니다.

아래 열 구성과 수식은 구글 시트에서도 그대로 동작합니다. 손익은 J열, 데이터는 2행부터 500행까지 있다고 가정했습니다.

엑셀로 만든 매매일지와 승률 집계표

매매일지 엑셀 양식에 넣을 열

열항목입력 예
A날짜날짜 서식으로 입력
B시간22:40
C통화쌍EURUSD(표기를 하나로 통일)
D방향매수 / 매도
E랏0.5
F진입가1.0850
G손절가1.0830
H청산가1.0875
Ipip수식으로 계산(아래 표)
J손익($)증권사 화면의 확정 손익을 옮겨 적기
K진입 이유돌파 후 눌림
L원칙 준수O / X
M감정차분함 / 조급함

통화쌍이 ‘EURUSD’ ‘유로달러’ ‘EUR/USD’로 섞이면 집계할 때 서로 다른 항목이 됩니다. 데이터 유효성 검사의 목록으로 고르게 해 두면 표기가 맞춰집니다. 방향과 O/X도 같은 방법을 씁니다.

손익은 직접 계산하기보다 증권사 HTS·MTS나 MT5 화면에 나오는 확정 손익을 옮기는 편이 정확합니다. 스와프와 수수료를 손익에 넣을지는 처음에 정해서 끝까지 같은 방식으로 적습니다.

SessionX

표를 짜는 수고를 덜고 싶다면, SessionX는 거래를 기록하기만 하면 승률과 통화쌍별·감정별 집계, 드로다운을 내 주고 엑셀에서 바로 열리는 CSV로도 내보낼 수 있습니다. Google Play에서 다운로드

pip와 누적 손익, 낙폭 수식

pip는 청산가와 진입가의 차이에 엔화가 들어간 통화쌍이면 100을, 그 밖의 통화쌍이면 10,000을 곱해 구합니다. 매도라면 빼는 순서를 반대로 합니다. I2에 아래 수식을 넣고 아래로 복사합니다.

셀수식의미
I2=IF(D2="매수",H2-F2,F2-H2)*IF(RIGHT(C2,3)="JPY",100,10000)방향을 보고 pip 계산
N2=SUM($J$2:J2)그 행까지의 누적 손익
O2=MAX(0,MAX($N$2:N2))그때까지 누적 손익의 최고치(고점)
P2=O2-N2고점에서 내려온 폭(드로다운)

예: EURUSD를 1.0850에 매수해 1.0875에 청산하면 (1.0875 - 1.0850) × 10,000 = 25pip입니다. USDJPY를 150.40에 매도해 150.10에 청산하면 (150.40 - 150.10) × 100 = 30pip입니다.

USDJPY처럼 결제 통화가 계좌 통화(달러)와 다른 통화쌍의 손익을 수식으로 내려면 그 시점의 환율이 필요합니다. 손익 열을 증권사 화면에서 옮겨 적는 이유가 여기에 있습니다. 1pip의 가치를 구하는 방법은 손절 기준과 포지션 사이즈 계산에 정리해 두었습니다.

엑셀로 승률·기대값·MDD 계산하는 법

집계 칸은 표 오른쪽이나 별도 시트에 둡니다. 손익이 0인 거래(본전 청산)는 이긴 거래에도 진 거래에도 넣지 않는 수식으로 짰습니다.

집계 항목수식
거래 횟수=COUNT(J2:J500)
이긴 횟수=COUNTIF(J2:J500,">0")
진 횟수=COUNTIF(J2:J500,"<0")
승률=COUNTIF(J2:J500,">0")/(COUNTIF(J2:J500,">0")+COUNTIF(J2:J500,"<0"))
평균 이익=AVERAGEIF(J2:J500,">0")
평균 손실=-AVERAGEIF(J2:J500,"<0")
실제 손익비=AVERAGEIF(J2:J500,">0")/-AVERAGEIF(J2:J500,"<0")
기대값(1회당)=AVERAGE(J2:J500)
프로핏 팩터=SUMIF(J2:J500,">0")/-SUMIF(J2:J500,"<0")
최대 낙폭 MDD($)=MAX(P2:P500)
원칙을 어긴 거래의 손익=SUMIF(L2:L500,"X",J2:J500)
EURUSD 손익 합계=SUMIF(C2:C500,"EURUSD",J2:J500)

승률 칸은 셀 서식을 백분율로 바꿉니다. 기대값이 플러스면 기록한 기간 동안 한 번 거래할 때마다 평균적으로 플러스였다는 뜻입니다. 승률과 손익비의 관계는 손익비 계산과 승률에서 계산기와 함께 설명합니다.

통화쌍별·요일별·감정별로 나눠 보고 싶다면 피벗 테이블이 편합니다. 행에 통화쌍(또는 감정 열)을, 값에 손익의 합계와 개수를 넣기만 하면 됩니다. 원칙 준수 열을 행에 넣으면 원칙을 지킨 거래와 어긴 거래의 성적이 한눈에 갈립니다.

해외선물·주식 매매일지 엑셀로 바꿔 쓰기

열의 뼈대는 그대로 두고 값을 재는 단위만 바꿉니다.

대상pip 열 대신손익 계산
FX마진pippip × 1랏당 1pip 가치 × 랏
해외선물틱 수틱 수 × 1틱 가치 × 계약 수
주식주당 차익(원)주당 차익 × 수량 - 수수료·세금

해외선물은 상품마다 1틱의 크기와 가치가 다르므로, 상품명 옆에 1틱 가치를 적는 열을 하나 더 두면 손익을 다시 계산하기 쉽습니다. 주식은 수수료와 세금을 뺀 금액을 손익 열에 넣어야 실제 계좌와 맞습니다.

MT5 기록을 엑셀로 가져오기와 계속 쓰는 요령

PC용 MT5는 거래내역(History) 탭의 오른쪽 클릭 메뉴에서 보고서를 만들 수 있습니다(MT5 도움말: 거래 보고서(영문)). 일시·종목·수량·가격·손익은 보고서에서 붙여 넣고, 진입 이유·원칙 준수·감정 세 열만 손으로 채우면 기록하는 수고가 크게 줄어듭니다.

FX마진거래와 해외선물은 증거금에 레버리지를 거는 파생상품 거래라서, 시세가 급변하면 반대매매로 포지션이 정리되거나 맡긴 증거금보다 손실이 커질 수도 있습니다. 이 글은 기록표를 만드는 방법에 대한 설명이며 특정 매매를 권하지 않습니다. 구조와 위험은 금융투자협회의 FX마진거래 투자자 유의사항에서 확인하시기 바랍니다.
SessionX

수식 없이 집계까지

SessionX는 MT5 기록(.xlsx 보고서)을 가져와 달력과 통계로 복기할 수 있는 FX 매매일지입니다.

Google Play에서 다운로드

iPhone 버전은 준비 중입니다

다른 가이드

가이드 전체 보기

출처

이 페이지는 SessionX 개발사 Zoranta가 작성했습니다.